Manage protection with Terraform

terraform {
  required_providers {
    clumio = {
      source  = "clumio-code/clumio"
      version = "~> 0.24.0"
    }
  }
}

provider "clumio" {}

export CLUMIO_API_TOKEN="<your_api_token>"
export CLUMIO_API_BASE_URL="https://us-west-2.api.clumio.com"

data "aws_caller_identity" "current" {}
data "aws_region" "current" {}

resource "clumio_aws_connection" "production" {
  account_native_id = data.aws_caller_identity.current.account_id
  aws_region        = data.aws_region.current.region
  description       = "Production workloads"
}

module "clumio_protect" {
  providers = {
    clumio = clumio
    aws    = aws
  }

  source                = "clumio-code/aws-template/clumio"
  clumio_token          = clumio_aws_connection.production.token
  role_external_id      = clumio_aws_connection.production.role_external_id
  aws_account_id        = clumio_aws_connection.production.account_native_id
  aws_region            = clumio_aws_connection.production.aws_region
  clumio_aws_account_id = clumio_aws_connection.production.clumio_aws_account_id

  is_ebs_enabled      = true
  is_rds_enabled      = true
  is_dynamodb_enabled = true
  is_s3_enabled       = true
}

resource "clumio_protection_group" "daily" {
  name = "daily-backup"

  bucket_rule = jsonencode({
    aws_tag = {
      "$eq" = {
        key   = "backup"
        value = "daily"
      }
    }
  })

  object_filter {
    storage_classes = ["S3 Standard", "S3 Standard-IA"]
  }
}

resource "clumio_policy" "daily" {
  name = "S3 daily"

  operations {
    action_setting = "immediate"
    type           = "protection_group_backup"

    slas {
      retention_duration {
        unit  = "months"
        value = 3
      }
      rpo_frequency {
        unit  = "days"
        value = 1
      }
    }

    advanced_settings {
      protection_group_backup {
        backup_tier = "cold"
      }
    }
  }
}

resource "clumio_policy_assignment" "daily" {
  entity_id   = clumio_protection_group.daily.id
  entity_type = "protection_group"
  policy_id   = clumio_policy.daily.id
}